Working With the XML DOM

I’ve been working with server side scripts that rely on xml files to define the structure of the site.  It seems quite fast compared to using a database and also makes direct changes to the structure easy.  My post here is about how to use the DOM in VBSCRIPT/ASP.  Some aspects of how the DOM works are a bit “wiggy” in my opinion, but I’ve figured out a lot of it so far.

Here is a quick example on how to parse a file (VBSCRIPT/ASP):

function parseXmlFile(filename, byRef emptyVarToFillWithXmlObj)

    dim completeFilePath, functionSuccess, filePointer

    

    completeFilePath = getFullPath() & filename

    

    ' Convert the xml file into an xmldoc object

    ' First check to see that the file exists

    set filePointer = server.createObject("Scripting.FileSystemObject")

    if filePointer.fileExists(completeFilePath) then

        ' Initialize the xml object

        set emptyVarToFillWithXmlObj = Server.CreateObject("Msxml2.DOMDocument.6.0")

        

        ' Make the object a standard synchronous type

        emptyVarToFillWithXmlObj.async = false

        

        ' Process the xml data file into the object

        ' Also save the success result from the function call

        functionSuccess = emptyVarToFillWithXmlObj.load(completeFilePath)

    else

        functionSuccess = false

    end if

    

    parseXmlFile = functionSuccess

end function

Pretty simple. This function checks to see if the file exists, if it does it uses the built-in xml dom objects to load the file and parse it.

Now I started working on a site to do change the xml files for me (aka. an administration site).  In this instance the DOM seems more confusing in how it works.

My main reason for posting this entry is to go over the DOM function insertBefore()

Here is an example code of how to flip two nodes:

' Example XML:
' <menu>
'   <item><name>item 01</name>...</item>
'   <item><name>item 02</name>...</item>
'   <item><name>item 03</name>...</item>
' </menu>

' objXmlData is the primary XML DOM object
if not objXmlData is nothing then
    ' we need to reference the first child of the file (menu tag)
    ' this will allow us to use the function insertBefore()
    set primaryNode = objXmlData.firstChild
    
    ' attempt to select the requested node
    set nodeToMove = objXmlData.selectSingleNode("menu/item[name='" & nodeName & "']")
    
    if not nodeToMove is nothing then
        ' select the node just before the requested one
        set nodeToBePushedDown = nodeToMove.previousSibling
        
        ' make sure something was found before trying to flip the items
        if not nodeToBePushedDown is nothing then
            ' insert the requested item before the first (flip them around)
            call primaryNode.insertBefore(nodeToMove, nodeToBePushedDown)
            
            ' save the change to the actual file
            call objXmlData.save(completeFilePathAndName)
        end if
        
        set nodeToBePushedDown = nothing
        set nodeToMove = nothing
    end if
    
    set primaryNode = nothing
end if

The key points to note here is that you need to first reference the first child of the primary XML DOM object. You can’t use objXmlData (the variable name I used) directly. So when you want to call the insertBefore function you use that “firstChild” element that we first loaded.

Another interesting function to note is the previousSibling() function. It easily allows us to select a node before another. This allows me in two functions to flip two xml nodes.